The HTML code you sent was missing the opening form tag which looks something like this:

<form action="Target_Web_Page.aspx" method="POST">

The action attribute tells the web browser where it should send all the form data when the submit is clicked. The method attribute tells the browser how to send the information. Valid values for this are "GET" or "POST". Don't worry about this right now, for what you are doing, stick with "POST".

 

Adding an opening form tag to the code you sent, the entire form code would be: (note that I made a few minor changes marked in red)

<form action="SendEmail.asp" method="POST">
Your Name:
<input type="text" name="FirstName" size="20"> 
<br>Your Last Name:
<input type="text" name="LastName" size="20"> 
<br> 
<br> 
<INPUT TYPE="checkbox" NAME="FlyingInformation" VALUE="Joes_page"> 
I am interested in more information about flying 
<br> 
<INPUT TYPE="checkbox" NAME="DemoFlight" VALUE="Joes_page"> 
I am interested in going on a demo flight 
<br> 
<br> 
<input type="submit" value="Submit"> 
</form>

The resulting form looks like this: (feel free to try it out by clicking the submit button - no email will actually be sent though)

Your Name:
Your Last Name:

I am interested in more information about flying
I am interested in going on a demo flight

When you click the submit button, send the information from all the fields in the form to the page specified in the action attribute. In the case of the form above, all the form information will be sent to SendEmail.asp It is this second page that will process the information.

Here is the code to the second page (SendMail.asp):
Please note that lines beginning with a single quote (') are comments and are ignored by the web server

<%
' This section is ASP code that is exected by the webserver
' First we want to build the email message from the form fields
' Form fields are stored in a Collection called Request.Form
' You access individual fields by specifying their name (from the Name attribute of the tag within the form)
' For example, the value filled into <input type="text" name="FirstName" size="20">  is stored in Request.Form("FirstName")
Dim sMessage
sMessage = "First Name: " & Request.Form("FirstName") & vbCrLf ' vbCrLf means to add a new line
sMessage = sMessage & "Last Name: " & Request.Form("LastName") & vbCrLf
' Checkboxes are handled slighly differently.  They are only present in the Request.Form Collection if the checkbox was checked.
' The specific value doesn't matter.  If ANY value is present, then the checkbox was checked
If Request.Form("FlyingInformation") <> "" Then
	sMessage = sMessage & "Requested Flying Information" & vbCrLf
End If
If Request.Form("DemoFlight") <> "" Then
	sMessage = sMessage & "Interested in Demo Flight" & vbCrLf
End If

' This next part will depend on the web server you have
' This is standard but is not supported by my web server
Dim oMail
Set oMail = CreateObject("CDO.Message") ' Create the mail object
oMail.Subject = "Information emailed from webpage"
oMail.From = "ari@gottunnel.com"
oMail.To = "Conundrum@dropzone.com"
oMail.TextBody = sMessage ' Use the message we built above
oMail.Send ' Send the message

' This is not as standard, but still widely used.  It's the only one supported by my web server
Set oMail = Server.CreateObject("Persits.MailSender") 
oMail.Host = "your.mailserver.com" ' You would have to update this with a valid outgoing mail server
oMail.From = "ari@gottunnel.com"
oMail.AddAddress "Conundrum@dropzone.com"
oMail.Subject = "Information emailed from webpage"
oMail.Body = sMessage ' Use the message we built above
oMail.Send ' Send the message
' End of ASP code that is exected by the webserver
%>

<html>
<head>
<title>Information Sent</title>
</head>
<body>
<h4>Thank you for sending your information!</h4>
</body>
</html>